plugins {
    id("com.android.application")
    id("org.jetbrains.kotlin.android")
}

// Version comes from versions.mk through the Makefile:
//   ./gradlew assembleRelease -PversionName=0.1.0 -PversionCode=1
val appVersionName = (project.findProperty("versionName") as String?) ?: "0.0.0"
val appVersionCode = ((project.findProperty("versionCode") as String?) ?: "1").toInt()

android {
    namespace = "cc.tiredsysadmin.android.keeporg"
    compileSdk = 35

    defaultConfig {
        applicationId = "cc.tiredsysadmin.android.keeporg"
        minSdk = 26
        targetSdk = 35
        versionCode = appVersionCode
        versionName = appVersionName
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            // Unsigned on purpose: the private F-Droid repository signs it.
            signingConfig = null
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = "17"
    }
    dependenciesInfo {
        // Keep the APK free of the Google dependency metadata blob so the
        // build is reproducible for F-Droid.
        includeInApk = false
        includeInBundle = false
    }
}